@Echo Off
CLS
Echo *************************************************************************
Echo * PATCH26C.BAT for T.A.G. version 2.6c to version 2.6c1    June 4, 1992 *
Echo * T.A.G. (C) Copyrighted 1986-1991 by Robert Numerick and Victor Capton *
Echo *************************************************************************
Echo.

If Exist TAG.EXE Goto OK1
Echo The file "TAG.EXE" was not found in the current directory.
Goto HowTo

:OK1
If Exist TAG.OVR Goto OK2
Echo The file "TAG.EXE" was not found in the current directory.
Goto HowTo

:OK2
If Exist EXE26C.DIF Goto OK3
Echo The file "EXE26C.DIF" was not found in the current directory.
Goto HowTo

:OK3
If Exist OVR26C.DIF Goto OK4
Echo The file "OVR26C.DIF" was not found in the current directory.
Goto HowTo

:OK4
If Exist REBUILD.EXE Goto OK5
Echo The file "REBUILD.EXE" was not found in the current directory.
Goto HowTo

:OK5
Echo *************************************************************************
Echo *            All required files are in place to run update.             *
Echo *     !!WARNING!! DO NOT RUN THIS PATCH MORE THAN ONCE !!WARNING!!      *
Echo *         Press RETURN to Continue, or ^C (Control C) to abort          *
Echo *************************************************************************
Echo.
PAUSE

REBUILD TAG.EXE TAGEXE.NEW EXE26C.DIF
If Errorlevel 1 Goto Fail
REBUILD TAG.OVR TAGOVR.NEW OVR26C.DIF
If Errorlevel 1 Goto Fail

Ren TAG.EXE TAGEXE.OLD
Ren TAGEXE.NEW TAG.EXE
Ren TAG.OVR TAGOVR.OLD
Ren TAGOVR.NEW TAG.OVR

Cls
Echo *************************************************************************
Echo *              Update to T.A.G. version 2.6c1 successful                *
Echo *                                                                       *
Echo *                  Cleanup Phase - Delete old files                     *
Echo *           TAGEXE.OLD, TAGOVR.OLD, EXE26C.DIF, OVR26C.DIF              *
Echo *                                                                       *
Echo *         Press RETURN to Continue, or ^C (Control C) to abort          *
Echo *************************************************************************
Echo.
PAUSE

Del TAGEXE.OLD
Del TAGOVR.OLD
Del EXE26C.DIF
Del OVR26C.DIF

Echo *************************************************************************
Echo *              Update to T.A.G. version 2.6c1 successful                *
Echo *                     Thanks for running T.A.G. !                       *
Echo *        Until Next Time, Happy BBSing!  ...  The T.A.G. Team           *
Echo *************************************************************************
Goto Exuant

:HowTo
Echo .
Echo *************************************************************************
Echo *    You must unzip ALL the files from the update file (TAGP26C.ZIP)    *
Echo *    into a directory containing the 2.6c T.A.G. EXE and OVR files.     *
Echo *    The following files MUST be in the current directory that this     *
Echo *    BAT file is invoked from.                                          *
Echo *    TAG.EXE, TAG.OVR                                                   *
Echo *    EXE26C.DIF, OVR26C.DIF                                             *
Echo *    REBUILD.EXE, PATCH26C.BAT                                          *
Echo *                                                                       *
Echo *          Update to T.A.G. version 2.6c1 NOT complete!                 *
Echo *************************************************************************
Goto Exuant

:Fail
If Exist TAGEXE.NEW Del TAGEXE.NEW
If Exist TAGOVR.NEW Del TAGOVR.NEW

Echo.
Echo *************************************************************************
Echo *                The conversion to 2.6c1 FAILED!                        *
Echo *                                                                       *
Echo *                    Possible reasons                                   *
Echo *      1. Wrong version of the TAG.EXE/OVR files (Must be 2.6c)         *
Echo *      2. Out of disk space                                             *
Echo *                                                                       *
Echo *          Update to T.A.G. version 2.6c1 NOT complete!                 *
Echo *************************************************************************
Goto Exuant

:Exuant
Rem  *************************************************************************
Rem  * PATCH26C.BAT for T.A.G. version 2.6c to version 2.6c1    June 3, 1992 *
Rem  * T.A.G. (C) Copyrighted 1986-1991 by Robert Numerick and Victor Capton *
Rem  *************************************************************************