@echo off
rem ZipLab Plus - EFT Interface batch
rem by Mike Ehlert 1:102/1001
rem
rem Read the ZLP-RA.DOC that came with this batch for more info.
rem
rem This will assume the enviornment variable %NODE% is set to the current
rem node number. For example "Set NODE=1" for line1, and so on.
rem If you don't run multinode, then you can replace "%NODE%" with "1"
rem
rem
rem First convert the RA DORINFO1.DEF to PCBOARD.DAT and PCBOARD.SYS files
rem RemoteAccess 1.10 should do this by itself , so a door converter such
rem as QuickDoor or Doormaster should then not be needed.
qkdoor c:\ra\line%NODE%\RA c:\ra\line%NODE%\PCB14
Rem Be sure the PCBDOOR variable is set as PRODOOR so ZipLab plus is happy.
Set PCBDOOR=PRODOOR
Rem Run Ziplab Plus (ptest) and pass it the filename and .cfg file to use.
c:\ra\ziplab\ptest.exe %1 c:\ra\ziplab\ptest%NODE%.cfg
rem If a file call PCBFAIL.TXT exists, that means that ziplab considers
rem the test to have failed. EFT does not care about such a filename,
rem EFT only checks if a file called GOOD exists, then the test passed.
rem So here we must create GOOD as long as there is no PCBFAIL.TXT.
if exist pcbfail.txt goto bad
echo good > GOOD
:bad
if exist pcbfail.txt erase pcbfail.txt
Rem May as well free up the enviornment by a few bytes...
Set PCBDOOR=
Rem Thats it, now its back to EFT.